Relative und absolute Bezüge
In dieser Lektion lernst du, wie du eine Formel in LibreOffice Calc mit dem Ausfüllkästchen auf viele Zeilen kopierst – und wie du mit Dollarzeichen steuerst, welche Zellbezüge dabei mitwandern und welche stehen bleiben.
Eine Formel kann für viele Zeilen kopiert werden. Dabei muss Calc wissen: Welche Zelladresse soll mitwandern und welche soll gleich bleiben?
Formeln kopieren mit dem Ausfüllkästchen
Wenn du eine Zelle anklickst, erscheint unten rechts an ihrem Rahmen ein kleines Quadrat: das Ausfüllkästchen (im Bild rot eingekreist). Ziehst du es mit gedrückter Maustaste nach unten, kopiert Calc die Formel in alle Zellen, über die du ziehst.
- Klicke die Zelle mit der Formel an, hier
C2. - Zeige mit der Maus auf das Ausfüllkästchen. Der Mauszeiger wird zu einem dünnen Kreuz.
- Ziehe nach unten bis zur letzten Zeile und lass los.
Du kannst eine Formel auch mit Strg + C kopieren und mit Strg + V in andere Zellen einfügen. Calc passt die Bezüge dabei genauso an.
Was ist ein Zellbezug?
Ein Zellbezug ist die Adresse einer Zelle. B2 bedeutet: Spalte B, Zeile 2.
Angenommen, in Spalte B stehen Preise und in F1 steht ein Wechselkurs. In C2 soll der erste Preis umgerechnet werden:
=B2*$F$1Kopierst du die Formel eine Zeile nach unten, passiert Folgendes:
| Formel in C2 | Formel in C3 | Warum? |
|---|---|---|
=B2*$F$1 |
=B3*$F$1 |
Der Preis wandert von B2 zu B3. Der Wechselkurs bleibt in F1. |
- Ein relativer Bezug wie
B2wandert beim Kopieren mit. - Ein absoluter Bezug wie
$F$1bleibt immer bei derselben Zelle.
Das Dollarzeichen hat hier nichts mit einer Währung zu tun. Es ist ein Feststeller: $F hält die Spalte F fest, $1 hält die Zeile 1 fest.
Warum reicht =B2*F1 nicht?
Calc verschiebt beim Kopieren jeden relativen Bezug um denselben Weg wie die Formel. Aus =B2*F1 in C2 wird deshalb eine Zeile tiefer =B3*F2.
Der Bezug auf den nächsten Preis ist richtig. Der Wechselkurs steht aber weiterhin in F1 und darf nicht zu F2 wandern. So sieht das Ergebnis aus, wenn man =B2*F1 trotzdem nach unten kopiert:
Nur die erste Zeile stimmt. In C3 rechnet Calc mit dem Rabatt aus F2, in C4 und C5 mit leeren Zellen. Calc zeigt dabei keine Fehlermeldung – das falsche Ergebnis fällt nur auf, wenn du es prüfst. Richtig ist =B2*$F$1.
Frage dich vor dem Kopieren bei jedem Zellbezug:
- Soll die Formel in der nächsten Zeile den nächsten Wert verwenden? Dann ohne
$. - Soll sie immer dieselbe Zelle verwenden? Dann Spalte und Zeile mit
$festhalten.
Zwei Feststeller – vier Möglichkeiten
Kopierst du eine Formel von C2 nach D4, liegt die Kopie eine Spalte weiter rechts und zwei Zeilen tiefer.
| Bezug in C2 | Bezug in D4 | Was ist fest? |
|---|---|---|
B2 |
C4 |
nichts |
$B$2 |
$B$2 |
Spalte und Zeile |
$B2 |
$B4 |
nur Spalte B |
B$2 |
C$2 |
nur Zeile 2 |
Die letzten beiden heißen gemischte Bezüge. Du brauchst sie vor allem, wenn du Formeln nicht nur nach unten, sondern auch nach rechts kopierst.
Eine Umrechnungstabelle soll Euro-Beträge in drei Währungen umrechnen. Die Beträge stehen in Spalte A, die Kurse in Zeile 2. Eine einzige Formel in B3 wird in den ganzen Bereich B3:D7 kopiert:
=$A3*B$2$A3: Der Betrag steht immer in Spalte A. Die Spalte wird festgehalten, die Zeile wandert mit.B$2: Der Kurs steht immer in Zeile 2. Die Zeile wird festgehalten, die Spalte wandert mit.
In D5 ist daraus =$A5*D$2 geworden: 50 € in Schweizer Franken.
- Bearbeite das Quiz „Wohin wandern die Bezüge?“. Sage darin vorher, was beim Kopieren entsteht.
- Schreibe anschließend die vier Bezüge aus der Tabelle in Calc, kopiere sie von
C2nachD4und vergleiche mit deinen Vorhersagen.
Ein Beispiel mit zwei festen Werten
In F1 steht der Wechselkurs und in F2 ein Rabatt. Beide Werte gelten für alle Angebote. Nur der Preis in Spalte B soll beim Kopieren wandern.
=B2*(1-$F$2)*$F$1Lies die Formel von links nach rechts: Preis aus dieser Zeile · Anteil nach Rabatt · fester Wechselkurs.
- Trage sechs Preise in
B2:B7, den Wechselkurs inF1und den Rabatt inF2ein. - Schreibe die Formel nur in
C2. Sage voraus, wie die Formel inC7lauten wird, und begründe, welche Bezüge wandern.
- Ziehe die Formel mit dem Ausfüllkästchen nach unten. Klicke anschließend
C7an und vergleiche die Formel in der Eingabezeile mit deiner Vorhersage. - Ändere den Rabatt. Alle Endpreise müssen sich ändern.